Lerne und übe ABAP – Uhr

Lerne und übe ABAP. In der ABAP-Übung „Clock“ implementierst Du eine einfache Uhr in der Programmiersprache ABAP. Dabei ist es sogar möglich, die Uhrzeit anzuzeigen. Es gibt 40 geniale ABAP Übungen auf exercism. Du kannst diese Übung entweder in Deinem SAP-System ausprobieren oder Dich kostenlos auf der Plattform anmelden und die Übung absolvieren. Du kannst Dir sogar Lösungen von anderen Nutzen ansehen und dadurch Deine Lösung vergleichen.

Aufgabenstellung

Implementiere eine Uhr, die Zeiten ohne Datum verarbeitet.

Du solltest in der Lage sein, Minuten zu addieren und zu subtrahieren.

Zwei Uhren, die die gleiche Zeit anzeigen, sollten gleich sein.

Beispiel Programmierung

CLASS zcl_clock DEFINITION
  PUBLIC
  CREATE PUBLIC.

  PUBLIC SECTION.

    METHODS constructor
      IMPORTING
        !hours   TYPE i
        !minutes TYPE i DEFAULT 0.
    METHODS get
      RETURNING
        VALUE(result) TYPE string.
    METHODS add
      IMPORTING
        !minutes TYPE i.
    METHODS sub
      IMPORTING
        !minutes TYPE i.

  PRIVATE SECTION.

    DATA clock TYPE t.

ENDCLASS.



CLASS zcl_clock IMPLEMENTATION.

  METHOD add.
    clock = clock + minutes * 60.
  ENDMETHOD.

  METHOD constructor.
    clock = hours * 60 * 60 + minutes * 60.
  ENDMETHOD.

  METHOD get.
    result = |{ clock+0(2) }:{ clock+2(2) }|.
  ENDMETHOD.

  METHOD sub.
    clock = clock - minutes * 60.
  ENDMETHOD.
ENDCLASS.

Erklärung

Dieses Programm implementiert eine Klasse zcl_clock zur Verwaltung von Zeiten ohne Datum. Die Klasse hat die folgenden öffentlichen Methoden:

• constructor: Diese Methode initialisiert den internen Zeitwert der Klasse. Als Eingabeparameter werden die Stunden und Minuten übergeben.
• get: Diese Methode gibt den aktuellen Zeitwert als String im Format „HH:MM“ zurück.
• add: Diese Methode addiert eine bestimmte Anzahl von Minuten zum internen Zeitwert.
• sub: Diese Methode subtrahiert eine bestimmte Anzahl von Minuten vom internen Zeitwert.

Der private Abschnitt definiert die Variable clock, das den internen Zeitwert speichert. Die Methode constructor berechnet aus den übergebenen Stunden und Minuten den Zeitwert in Sekunden und speichert diesen in der Variable clock. Die Methoden add und sub verändern den Zeitwert entsprechend durch Addition bzw. Subtraktion von Minuten in Sekunden. Die Methode get formatiert den Zeitwert als String und gibt ihn zurück.