SAP-Benutzer ermitteln

Im SAP-System arbeiten mehre SAP-Benutzer zeitgleich. Dabei besitzt jeder SAP-Benutzer eine eindeutige ID, die man während der Anmeldung am SAP-System verwendet. So muss das auch sein, da es in einem Unternehmen durchaus Personen geben kann, die die gleichen Vor- und Nachnamen besitzen.

In diesem Artikel zeige ich Dir, wie Du einfach und schnell den SAP-Benutzer ermitteln kannst. Dabei kannst Du sowohl vom SAP-Benutzer auf den Vor- und Nachnamen schließen und andersherum. Das ist deshalb notwendig, um herauszufinden, wer welche Aktionen im SAP-System durchgeführt hat.

SAP-Benutzer ermitteln

In diesem Szenario kennen wir den Vor- und Nachnamen des Anwenders und möchten seinen SAP-Benutzernamen bzw. seine ID ermitteln.

Man kann am einfachsten den SAP-Benutzernamen ermitteln, in dem man die F4-Hilfe des Eingabefeldes für SAP-Benutzer verwendet. Hinter so einem Eingabefeld steckt das Datenelement XUBNAME, die Domäne XUBNAME und die Suchhilfe USER_COMP. Dabei werden nur Werte der Wertetabelle USR02 angezeigt.

In folgenden Transaktionen kann man die F4-Hilfe des Eingabefeldes bspw. benutzen:

• SU01 / SU01D
• SE01 / SE09 / SE10

Zudem hinaus kann man sich einen eigenen ABAP-Report programmieren, um die gewünschten Ergebnisse zu ermitteln.

TYPES: BEGIN OF ty_usr,
         bname      TYPE suid_st_bname-bname,
         name_first TYPE ad_namefir,
         name_last  TYPE ad_namelas.
TYPES END OF ty_usr.

DATA: lv_fname TYPE ad_namefir,
      lv_lname TYPE ad_namelas,
      lt_usr   TYPE TABLE OF ty_usr.

" Eingebaute Wertehilfe USER_COMP übernehmen
PARAMETERS: p_uname TYPE suid_st_bname-bname,
            p_fname TYPE ad_namefir,
            p_lname TYPE ad_namelas.

REPLACE ALL OCCURRENCES OF '*' IN p_uname WITH '%'.
REPLACE ALL OCCURRENCES OF '*' IN p_fname WITH '%'.
REPLACE ALL OCCURRENCES OF '*' IN p_lname WITH '%'.

IF p_uname IS INITIAL.
  p_uname = '%'.
ENDIF.

IF p_fname IS INITIAL.
  p_fname = '%'.
ENDIF.

IF p_lname IS INITIAL.
  p_lname = '%'.
ENDIF.

" Datenselektion
SELECT usr~bname adr~name_first adr~name_last
  FROM usr21 AS usr JOIN adrp AS adr
    ON usr~persnumber = adr~persnumber
  INTO TABLE lt_usr
  WHERE adr~name_first LIKE p_fname
  AND   adr~name_last LIKE p_lname.

" Ausgabe
LOOP AT lt_usr ASSIGNING FIELD-SYMBOL(<fs_usr>).
  WRITE: / <fs_usr>-bname, ', ', <fs_usr>-name_first, ', ', <fs_usr>-name_last.
ENDLOOP.

Vor- und Nachname ermitteln

Kennt man den SAP-Benutzernamen und möchte nun wissen, welche Person dahinter steckt, kann man das ebenfalls einfach und schnell in SAP ERP bzw. SAP S/4HANA herausfinden. Hierzu kann man das gleiche Vorgehen verwenden wir im vorherigen Abschnitt. Man benutzt die existierende Suchhilfe USER_COMP im Eingabefeld für SAP-Benutzer.

Dazu ruft man eine SAP-Transaktion auf, die so ein Eingabefeld zur Verfügung stellt (z.B. SU01, SU01D, SE01, SE09 oder SE10) und benutzt die F4-Hilfe. Anschließend werden die Vor- und Nachnamen in der Suchhilfe zum SAP-Benutzer angezeigt.

Alternativ kann man im ABAP-Dictionary (Transaktion SE11) die Suchhilfe O2USERNAME aufrufen und mit dem SAP-Benutzer testen, um sich den Vor- und Nachnamen anzeigen zu lassen.

Außerdem kann man mit dem Funktionsbaustein BAPI_USER_GET_DETAIL im Function Builder (Transaktion SE37) zahlreiche Daten des SAP-Benutzers ermitteln. So auch die Adressdaten, zu denen der Vor- und Nachname zählen.

Mithilfe der Tabellen USR21 und ADRP kann man sich ebenfalls einen eigenen ABAP-Report programmieren, um die gewünschten Daten zu selektieren.

E-Mail-Adresse ermitteln

Die E-Mail-Adresse wird leider nicht mit der Suchhilfe USER_COMP angezeigt. Man muss sich also über eine Datenselektion die Daten eigenständig beschaffen. Die E-Mail-Adresse wird in der Tabelle ADR6 gespeichert.

Kennt man den SAP-Benutzer, kann man ebenfalls die E-Mail-Adresse ermitteln. Dafür verwendet man nun die Tabellen USR21 und ADR6. Mit einem ABAP-Report kann man somit über einen JOIN die gewünschte E-Mail-Adresse selektieren.

TYPES: BEGIN OF ty_usr,
         bname      TYPE suid_st_bname-bname,
         persnumber TYPE ad_persnum,
         smtp_addr  TYPE ad_smtpadr,
       END OF ty_usr.
DATA: ls_usr TYPE ty_usr.
PARAMETERS: p_name TYPE suid_st_bname-bname DEFAULT 'ANDREASG'.

*----------------------------------------------------------------------
* Datenselektion
*----------------------------------------------------------------------
SELECT SINGLE u~bname,
       u~persnumber,
       a~smtp_addr
  INTO @ls_usr
  FROM usr21 AS u
  JOIN adr6 AS a ON a~persnumber = u~persnumber AND a~addrnumber = u~addrnumber
  WHERE u~bname = @p_name.

Mit dem Funktionsbaustein BAPI_USER_GET_DETAIL kann man in der Tabelle ADDSMTP die E-Mail-Adresse ebenfalls ermitteln.

SAP-Benutzer kontaktieren

Es gibt diverse Möglichkeiten, einen SAP-Benutzer kontaktieren. Man kann der Person natürlich eine E-Mail schreiben oder sie direkt anrufen. Aber SAP ERP bzw. SAP S/4HANA bieten nützliche Funktionen, um direkt im SAP-System selbst zu kommunizieren:

• Funktionsbaustein TH_POPUP
• Eigener Report
• Systemmeldungen
• Kurznachrichten

Im Artikel „Einfach Nachrichten in SAP ERP verschicken“ werden diese Möglichkeiten im Detail vorgestellt.