SAP TM – Alle Frachtabrechnungsbelege zu Frachtauftrag

In diesem Artikel zeige ich Dir, wie Du mit Hilfe von ABAP in SAP TM alle gültigen Frachtabrechnungsbelege zu einem Frachtauftrag ermitteln kannst.

SAP Transportation Management (SAP TM) ist ein spezialisiertes Modul, das Unternehmen unterstützt, den gesamten Transportprozess effizient zu organisieren. Hauptfunktionen von SAP TM sind:

• Erstellung von Speditionsaufträgen
• Integration mit SAP ERP
• Verwaltung und Optimierung von Frachtbuchungen
• Automatisierte Auswahl von Spediteuren
• Durchführung von Transportausschreibungen
• Echtzeit-Tracking von Transporten
• Präzise Kalkulation von Transportkosten
• Einhaltung von Vorschriften und Standards

SAP TM bietet Funktionen für:

• Effektives Speditionsauftragsmanagement
• Effizientes Frachtauftragsmanagement
• Präzise Transportplanung
• Schnelle und genaue Abrechnung
• Zuverlässiges Stammdaten- und Transportnetzmanagement

Diese Funktionen helfen Unternehmen, ihre Transportprozesse effizienter und kostengünstiger zu gestalten.

SAP TM – Alle Frachtabrechnungsbelege zu Frachtauftrag

FUNCTION Z_TM_FIND_FSD_FOR_FO.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(IM_FREIGHT_ORDER) TYPE  /SCMTMS/TOR_ID
*"  EXPORTING
*"     REFERENCE(EX_TT_FSD) TYPE  Z_TT_TM_FSD
*"  EXCEPTIONS
*"      NO_FSD_FOUND
*"----------------------------------------------------------------------
**********************************************************************
*** Benutzerdefinierte Logik zur Ermittlung des Frachtabrechnungsbelegs
*** für einen Frachtauftrag
***
*** Tabellen:
*** 1. /SCMTMS/D_TORROT - Root Node
*** 2. /SCMTMS/D_SF_ITM - Table Main Area : SFIR Item
*** 3. /SCMTMS/D_SF_ROT - Table for Root Node
**********************************************************************
  TYPES: BEGIN OF ty_parent_key,
           parent_key TYPE /bobf/conf_key,
         END OF ty_parent_key.

  DATA: lv_fo         TYPE /scmtms/tor_id,
        lv_node_id    TYPE /bobf/conf_key,
        lt_parent_key TYPE TABLE OF ty_parent_key,
        lt_fsd        TYPE z_tt_tm_fsd.

  " Umrechnung für Frachtauftrag erforderlich
  CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
    EXPORTING
      input  = im_freight_order
    IMPORTING
      output = lv_fo.

  SELECT SINGLE db_key FROM /scmtms/d_torrot INTO lv_node_id
    WHERE tor_id = lv_fo ##WARN_OK.

  IF sy-subrc NE 0 OR lv_node_id IS INITIAL.
    RAISE no_fsd_found.
  ELSE. "SY-SUBRC = 0
    SELECT parent_key FROM /scmtms/d_sf_itm INTO TABLE lt_parent_key
      WHERE tor_root_key = lv_node_id.

    IF sy-subrc NE 0 OR lt_parent_key IS INITIAL.
      RAISE no_fsd_found.
    ELSE.
      SELECT sfir_id lifecycle FROM /scmtms/d_sf_rot INTO CORRESPONDING FIELDS OF TABLE lt_fsd
        FOR ALL ENTRIES IN lt_parent_key           "#EC CI_NO_TRANSFORM
        WHERE db_key = lt_parent_key-parent_key
        AND sfir_category = '10'. "Freight Settlement Document
      IF sy-subrc NE 0 OR lt_fsd IS INITIAL.
        RAISE no_fsd_found.
      ELSE.
        ex_tt_fsd = lt_fsd.
      ENDIF.
    ENDIF.
  ENDIF.

**********************************************************************
*** Versuch, über Join alle Frachtabrechnungsbelege zu Frachtauftrag
*** zu ermitteln
**********************************************************************
***  DATA: lt_fsd        TYPE /lxs0/vim_tt_17445_tm_fsd.
***
***  SELECT c~sfir_id c~lifecycle INTO TABLE lt_fsd
***    FROM /scmtms/d_torrot AS a
***      JOIN /scmtms/d_sf_itm AS b ON a~db_key = b~tor_root_key
***        JOIN /scmtms/d_sf_rot AS c ON b~parent_key = c~db_key
***    WHERE a~tor_id = im_freight_order
***      AND c~sfir_category = '10'. "Freight Settlement Document
***
***  IF sy-subrc NE 0 OR lt_fsd IS INITIAL.
***    RAISE no_fsd_found.
***  ELSE.
***    ex_tt_fsd = lt_fsd.
***  ENDIF.

ENDFUNCTION.